【 아두이노Proj#8】 사륜구동 4WD 블루투스 RC카 만들기~! (with 모터쉴드)

【 아두이노Proj#8】 사륜구동 4WD 블루투스 RC카 만들기~! (with 모터쉴드)

 지난시간, 블루투스모듈을 이용한 통신을 학습하였다. 또한 미니카도 만들어 제어해보았는데, 이제 이 것들을 종합해서 업그레이드 해보도록 하자! 

 바퀴 4개를 이용하여 4륜 구동으로 만들고 아두이노 프로미니로 소형 리모컨을 만들어 무선제어를 한다면, 교육적이고 멋진 아두이노 장난감을 만들어 낼 수 있다.  여기에 Adafruit 사의 모터쉴드를 이용하면, 별다른 선연결도 없이 간단히 4개의 DC모터를 제어할 수 있다.

Let's get it~!

 

▶ 선수 학습 :

    1. [아두이노 모듈#16] 아두이노... 블루투스통신 (블루투스 설정법 참조) ☜ (클릭)

    2. [아두이노 모듈#18] 아두이노... 블루투스통신 (블루투스 제어법 참조) ☜ (클릭)

    3. [아두이노 모듈#22] Adafruit의 4채널 모터쉴드(모터쉴드 사용법 참조) ☜ (클릭)
    4. [아두이노 ProMini#2] 초소형 블루투스 리모컨 만들기(리모트 컨트롤러 참조) ☜ (클릭)

 

▶ 실습 목표 :  

 1. [ Adafruit 모터 쉴드의 사용법을 익힐 수 있고 4개의 DC모터 제어를 할 수 있다.] 

 2. [ 조이스틱의 컨트롤 기능을 익힐 수 있다.  ]

 3. [ 블루투스 모듈의 셋업과 페어링(연결) 및 사용법을 익힐 수 있다. ]

 4. [ 아두이노 두 대 상호간 통신을 통해 제어하는 방법을 익힐 수 있다 ]

 

▶ 실습 회로도면 :
  (이미지 클릭하면 확대 가능)

[1.  사륜 구동 본체 연결도]

[2. 블루투스 리모컨 연결도]

- 1. 우노 리모컨

우노(나노)보드 조이스틱 조정기 연결도

- 2. 프로미니 리모컨

프로미니 보드 조이스틱 조정기 연결도

※ 블루투스 페어링(자동 연결)을 위해서는, 선수학습 1번을 통해 블루투스 설정법을 확인하여, 본체에 있는 블루투스 모듈은 슬레이브로(Slave)로 설정하고, 조이스틱 조정기의 블루투스는 마스터(Master) 설정 작업이 필요하다.  
(물론 마스터와 슬레이브가 반대로 바뀌어도 상관이 없다)

  - 선수학습을 참고하면 좀더 상세하게 조이스틱 컨트롤로(조정기) 회로를 조립할 수 있다.

  - 우노회로나, 프로미니 회로 모두 같은 코드를 사용하니 상황에 따라 적합한 것을 선택할 수 있다.

 

▶ 실습 절차  :  

1.   부품을 준비하여 위와 같은 회로를 각각 구성한다. 

   -  사륜카의 베이스 판은 아크릴 판 혹은 MDF 등 주변에서 쉽게 구할 수 있는 것으로 사용해도 무방하다.

   -  여기서는 3D 프린팅으로 출력한 것을 베이스로 사용하였다.

   -  모터와 베이스를 연결하는 적합한 나사가 없을 경우, 두꺼운 양면테잎 혹은 글루스틱으로 부착하여도 무방.

   -  3.7V 베터리 2개를 직렬연결 해주면, 충분한 전류가 공급되어 힘있고 빠르게 구동된다.

2.   아래 코드를 작성하고 각각의 프로그램을 로딩 후 실행시킨다.

 

 

▶ 프로그램 코드 및 설명  : 

 

【 코드1-본체 】

#include  <AFMotor.h>            // Adafruit 모터 쉴드 라이브러리 사용
#include  <SoftwareSerial.h>    //블루투스 통신을 위한 기본 헤더 선언
                                 
SoftwareSerial BTSerial(2, 3);  // 블루투스 모듈과 통신을 위한 아두이노 연결핀(TX = 2 , RX = 3)
//모터의 전후좌우 방향을 컨트롤하는 PIN번호를 상수로 선언
AF_DCMotor MOTOR1(1);     // 모터쉴드 M1 지정
AF_DCMotor MOTOR2(2);     // 모터쉴드 M2 지정
AF_DCMotor MOTOR3(3);     // 모터쉴드 M3 지정
AF_DCMotor MOTOR4(4);     // 모터쉴드 M4 지정
#define ActionTime 3000
/*  for (i=0; i <255; i++) {
    motor.setSpeed(i);
    delay(20);
  }
*/
void Stop_Release() {
  MOTOR1.run(RELEASE);
  MOTOR2.run(RELEASE);
  MOTOR3.run(RELEASE);
  MOTOR4.run(RELEASE);
  delay(20);
}

void Go_Forward() {
  MOTOR1.run(FORWARD);
  MOTOR2.run(FORWARD);
  MOTOR3.run(FORWARD);
  MOTOR4.run(FORWARD);
  delay(20);
}

void Go_Backward() {
  MOTOR1.run(BACKWARD);
  MOTOR2.run(BACKWARD);
  MOTOR3.run(BACKWARD);
  MOTOR4.run(BACKWARD);
  delay(20);
}

void Go_Left() {
  MOTOR1.run(FORWARD);
  MOTOR2.run(BACKWARD);
  MOTOR3.run(BACKWARD);
  MOTOR4.run(FORWARD);
  delay(20);
}

void Go_Right() {
  MOTOR1.run(BACKWARD);
  MOTOR2.run(FORWARD);
  MOTOR3.run(FORWARD);
  MOTOR4.run(BACKWARD);
  delay(20);
}

void setup() {
  BTSerial.begin(9600); //블루투스와 통신하기 위한 속도설정(모듈의속도 확인필요)
  Serial.begin(9600);   // 시리얼(모니터) 통신 속도를 설정
  MOTOR1.setSpeed(250);
  MOTOR2.setSpeed(250);
  MOTOR3.setSpeed(250);
  MOTOR4.setSpeed(250);
}

void loop() {
/* 기본 동작  
  Go_Forward();
  Stop_Release();
  Go_Left();
  Stop_Release();
  Go_Right();
  Stop_Release();
  Go_Backward();
  Stop_Release();
*/
  if (BTSerial.available()) {   // 블루투스로 신호가 있을 경우 실행되는 루틴
    char cmd = (char) BTSerial.read();   // 블루투스로 읽은 값을 char타입 변수에 저장
    Serial.println(cmd);  //cmd변수에 저장된 내용을 사용자가 `시리얼모니터`로 확인
    
    if ( cmd == 'f') {          //블루투스에서 'f'값이 들어오면 전진
      Go_Forward();
    } else if (cmd == 'l') {     //블루투스에서 'l'값이 들어오면 좌회전
        Go_Left();
    } else if (cmd == 'r') {     //블루투스에서 'r'값이 들어오면 우회전
        Go_Right();
    } else if (cmd ==  'b') {    //블루투스에서 'b'값이 들어오면 후진
        Go_Backward();
    } else if (cmd == 's') {    //블루투스에서 's'값이 들어오면 멈춤
        Stop_Release();
    }
  }
}

 

【 코드2-조이스틱 조정기 】

/*  블루투스 조이스틱 조정기 만들기        */
#include  <SoftwareSerial.h>
SoftwareSerial BTSerial(2, 3);  // BTSerial(Rx, Tx)
int BTstates=0;       // 블루투스 신호 상태 저장용 변수
const int X_AXIS =0; //마우스 X 축 (A0)
const int Y_AXIS =1; //마우스 Y 축 (A1) 
int xVal=0;
int yVal=0;

void setup() {
  BTSerial.begin(9600);  
  Serial.begin(9600);
}

void loop() {  
  xVal=map(analogRead(X_AXIS),0,1023,100,0); //x축값 읽어 저장 
  yVal=map(analogRead(Y_AXIS),0,1023,300,200); //Y축값 읽어 저장
  
  // 모터 전진 //
  if (xVal >= 60 && yVal >= 225 && yVal <=275)  { 
    BTSerial.write('f');
    Serial.println('f');
  }
  
  // 모터 후진 //
  else if (xVal <= 40 && yVal >= 225 && yVal <=275)  { 
    BTSerial.write('b');
    Serial.println('b');
  }
  
  // 모터 좌회전 //
  else if (yVal <= 240 && xVal >= 25 && xVal <= 75)  { 
    BTSerial.write('l');
    Serial.println('l');
  }

  // 모터 우회전 //
  else if (yVal >= 260 && xVal >= 25 && xVal <= 75)  { 
    BTSerial.write('r');
    Serial.println('r');
  }

 else { 
    BTSerial.write('s');
    Serial.print('s');
  }
  delay(100); 
}

 

▶ 코드 다운로드 :

 (위 두 가지 코드 압축파일로 다운로드)

(PROJ03) 4WD_CAR.zip

0.00MB

 

위 코드에 사용된  AFMotor.h 라이브러리 첨부 :

Adafruit-Motor-Shield.zip

0.01MB

(만약 위 라이브러리를 다운 받아 추가 할 경우, 압축을 풀지말고, 아두이노 라이브러리 포함하기 메뉴에서 .zip 라이브러리 추가... 메뉴를 이용해서 추가해주세요. )

 

 

▶ 회로 제작/동작 영상 :

(YouTube : 1080P 고화질로 보기)

https://youtu.be/0tEaw29_dJc

 

(카카오로 보기)

 

 

▶ 프로젝트 제작에 사용된 3D 프린팅용 파일 :

1. Car 베이스
( 1. 아래는 본 영상에 사용된 Car-베이스 오리지널 출력 파일 입니다.
오리지널 파일은 고정용 나사 구멍이 뚫려 있습니다.)

아래 파일 출력 예상 이미지

 

ORIGINAL_chasis01.STL

0.27MB

( 2. 아래는 직경이 다소 큰 바퀴를 사용할 경우 가운데 부분이 걸릴 수 있어 바퀴 나뉘는 부분을 좀더 좁게 , 그리고 두께를 4t 정도 되도록한 파일 입니다.  그리고 직접 드릴로 나사의 고정 위치를 잡도록 나사구멍이 없는 파일입니다. 
- 다만, 수정한 파일은 직접 출력해서 테스트해 보지 않았기에, 먼저 오리지널 파일을 사용해 보시고 필요할 경우 아래 파일을 출력해 보시기 바랍니다.)

아래 파일 출력 예상 이미지

Rasino_4WheelCar_base_01.stl

1.48MB

2. 모터 고정용 브라켓
(본 게시글에 사용된 모터를 Car 베이스에 고정하기 위한 브라켓 입니다. )
아래 출력용 모터 서포터는 좌측용과 우측용 2가지이며,  각각 2개씩 총 4개를 출력하면 됩니다.

아래 파일 출력 예상 이미지

soporte_motor1.STL

0.04MB

soporte_motor2.STL

0.04MB

3. 모터 고정용 전용 브라켓(M3 나사) 별도 구매용
( 위 2번의 브라켓은 출력용이다 보니 아무래도 RC-Car를 운행 할 수록 Car 베이스에 단단히 고정되지 않고 흔들거릴 수 있습니다.  때문에,   본 게시글에 사용된 모터 전용 M3나사 브라켓을 별도로 구매해서 고정시키셔도 좋을 것 같습니다.)

브라켓 구매 링크 :  smartstore.naver.com/domekit/products/2988750683  (2개 1셋 이기 때문에 구매하실때는 2개구매 혹은 여유 있게 구매)